idl/GEOM_Gen.idl

Go to the documentation of this file.

// Copyright (C) 2005  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
// 
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either 
// version 2.1 of the License.
// 
// This library is distributed in the hope that it will be useful 
// but WITHOUT ANY WARRANTY; without even the implied warranty of 
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU 
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public  
// License along with this library; if not, write to the Free Software 
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
//  File   : GEOM_Gen.idl
//  Author : Sergey RUIN

#ifndef __GEOM_GEN__
#define __GEOM_GEN__

#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"
#include "SALOMEDS.idl"

#include "SALOME_GenericObj.idl"

module GEOM
{
  enum shape_type { COMPOUND, COMPSOLID, SOLID, SHELL,
                 FACE, WIRE, EDGE, VERTEX, SHAPE };


  enum shape_state
  {
    ST_ON,

    ST_OUT,

    ST_ONOUT,

    ST_IN,

    ST_ONIN
  };

  typedef sequence<string>      string_array;
  typedef sequence<short>       short_array;
  typedef sequence<long>        ListOfLong;
  typedef sequence<double>      ListOfDouble;

  interface GEOM_Object;

  typedef sequence<GEOM_Object> ListOfGO;

  interface GEOM_Object : SALOME::GenericObj
  {

    string GetEntry();

    long GetStudyID();

    long GetType();

    shape_type GetShapeType();

    void SetName (in string theName);

    string GetName();

    void SetStudyEntry (in string theEntry);

    string GetStudyEntry();

    ListOfGO GetDependency();

    ListOfGO GetLastDependency();

    long getShape();

    SALOMEDS::TMPFile GetShapeStream();

    /*
     *  Returns True if this object is not a sub shape of another object.
     */
    boolean IsMainShape();

    /*
     *  Get a list of ID's of sub shapes in the main shape.
     *  \note Internal method, suppopsed to be used only by GEOM_Client
     */
    ListOfLong GetSubShapeIndices();

    /*
     *  Get a main shape object to which this object is a sub shape
     *  \note Internal method, suppopsed to be used only by GEOM_Client
     */
    GEOM_Object GetMainShape();

    /*
     *  Return true if geom object representes a shape.
     *  For example, method return false for GEOM_MARKER
     */
     boolean IsShape();
  };


  interface GEOM_IOperations : SALOME::GenericObj
  {
    boolean IsDone();

    void SetErrorCode (in string theErrorID);

    string GetErrorCode();

    long GetStudyID();

    void StartOperation();

    void FinishOperation();

    void AbortOperation();
  };

  interface GEOM_IBasicOperations : GEOM_IOperations
  {
    GEOM_Object MakePointXYZ (in double theX, in double theY, in double theZ);

    GEOM_Object MakePointWithReference (in GEOM_Object theReference,
                         in double theX, in double theY, in double theZ);

    GEOM_Object MakePointOnCurve (in GEOM_Object theRefCurve,
                      in double theParameter);

    
     GEOM_Object MakeTangentOnCurve (in GEOM_Object theRefCurve,
                         in double theParameter);

    GEOM_Object MakeVectorDXDYDZ (in double theDX,
                      in double theDY,
                      in double theDZ);

    GEOM_Object MakeVectorTwoPnt (in GEOM_Object thePnt1, in GEOM_Object thePnt2);

    GEOM_Object MakeLine (in GEOM_Object thePnt, in GEOM_Object theDir);

    GEOM_Object MakeLineTwoPnt (in GEOM_Object thePnt1, in GEOM_Object thePnt2);

    GEOM_Object MakePlaneThreePnt (in GEOM_Object thePnt1,
                       in GEOM_Object thePnt2,
                       in GEOM_Object thePnt3,
                       in double theTrimSize);

    GEOM_Object MakePlanePntVec (in GEOM_Object thePnt,
                     in GEOM_Object theVec,
                     in double theTrimSize);

    GEOM_Object MakePlaneFace (in GEOM_Object theFace,
                      in double theTrimSize);

    GEOM_Object MakeMarker (in double theOX , in double theOY , in double theOZ,
                   in double theXDX, in double theXDY, in double theXDZ,
                   in double theYDX, in double theYDY, in double theYDZ);
     
    GEOM_Object MakeTangentPlaneOnFace(in GEOM_Object theFace,
                           in double theParameterU,
                           in double theParameterV,
                           in double theTrimSize);
  };

  interface GEOM_ITransformOperations : GEOM_IOperations
  {
    GEOM_Object TranslateTwoPoints (in GEOM_Object theObject,
                        in GEOM_Object thePoint1,
                        in GEOM_Object thePoint2);

    GEOM_Object TranslateTwoPointsCopy (in GEOM_Object theObject,
                         in GEOM_Object thePoint1,
                                        in GEOM_Object thePoint2);

    GEOM_Object TranslateDXDYDZ (in GEOM_Object theObject,
                     in double theDX, in double theDY, in double theDZ);

    GEOM_Object TranslateDXDYDZCopy (in GEOM_Object theObject,
                         in double theDX, in double theDY, in double theDZ);


    GEOM_Object TranslateVector (in GEOM_Object theObject,
                     in GEOM_Object theVector);

    GEOM_Object TranslateVectorCopy (in GEOM_Object theObject,
                         in GEOM_Object theVector);

    GEOM_Object MultiTranslate1D (in GEOM_Object theObject,
                      in GEOM_Object theVector,
                      in double theStep,
                      in long theNbTimes);

    GEOM_Object MultiTranslate2D (in GEOM_Object theObject,
                      in GEOM_Object theVector1,
                      in double theStep1,
                      in long theNbTimes1,
                      in GEOM_Object theVector2,
                      in double theStep2,
                      in long theNbTimes2);

    GEOM_Object Rotate (in GEOM_Object theObject,
               in GEOM_Object theAxis,
               in double theAngle);

    GEOM_Object RotateCopy (in GEOM_Object theObject,
                   in GEOM_Object theAxis,
                   in double theAngle);

    GEOM_Object MultiRotate1D (in GEOM_Object theObject,
                      in GEOM_Object theAxis,
                      in long theNbTimes);

    GEOM_Object MultiRotate2D (in GEOM_Object theObject,
                      in GEOM_Object theAxis,
                      in double theAngle,
                      in long theNbTimes1,
                      in double theStep,
                      in long theNbTimes2);

    GEOM_Object MirrorPlane (in GEOM_Object theObject, in GEOM_Object thePlane);

    GEOM_Object MirrorPlaneCopy (in GEOM_Object theObject, in GEOM_Object thePlane);

    GEOM_Object MirrorAxis (in GEOM_Object theObject, in GEOM_Object theAxis);

    GEOM_Object MirrorAxisCopy (in GEOM_Object theObject, in GEOM_Object theAxis);

    GEOM_Object MirrorPoint (in GEOM_Object theObject, in GEOM_Object thePoint);

    GEOM_Object MirrorPointCopy (in GEOM_Object theObject, in GEOM_Object thePoint);

    GEOM_Object OffsetShape (in GEOM_Object theObject, in double theOffset);

    GEOM_Object OffsetShapeCopy (in GEOM_Object theObject, in double theOffset);

    GEOM_Object ScaleShape (in GEOM_Object theObject, in GEOM_Object thePoint,
                   in double theFactor);

    GEOM_Object ScaleShapeCopy (in GEOM_Object theObject, in GEOM_Object thePoint,
                    in double theFactor);

    GEOM_Object PositionShape (in GEOM_Object theObject,
                      in GEOM_Object theStartLCS,
                      in GEOM_Object theEndLCS);

    GEOM_Object PositionShapeCopy (in GEOM_Object theObject,
                       in GEOM_Object theStartLCS,
                       in GEOM_Object theEndLCS);
  };

  interface GEOM_I3DPrimOperations : GEOM_IOperations
  {
    GEOM_Object MakeBoxDXDYDZ (in double theDX, in double theDY, in double theDZ);

    GEOM_Object MakeBoxTwoPnt (in GEOM_Object thePnt1, in GEOM_Object thePnt2);

    GEOM_Object MakeCylinderRH (in double theR, in double theH);

    GEOM_Object MakeCylinderPntVecRH (in GEOM_Object thePnt,
                          in GEOM_Object theAxis,
                          in double      theR,
                          in double      theH);

    GEOM_Object MakeConeR1R2H (in double theR1, in double theR2, in double theH);

    GEOM_Object MakeConePntVecR1R2H (in GEOM_Object thePnt,
                         in GEOM_Object theAxis,
                         in double      theR1,
                         in double      theR2,
                         in double      theH);

    GEOM_Object MakeTorusRR (in double theRMajor,
                    in double theRMinor);

    GEOM_Object MakeTorusPntVecRR (in GEOM_Object thePnt,
                       in GEOM_Object theVec,
                       in double theRMajor,
                       in double theRMinor);

    GEOM_Object MakeSphereR (in double theR);

    GEOM_Object MakeSpherePntR (in GEOM_Object thePnt, in double theR);

    GEOM_Object MakePrismVecH (in GEOM_Object theBase,
                      in GEOM_Object theVec,
                      in double      theH);

    GEOM_Object MakePrismTwoPnt (in GEOM_Object theBase,
                     in GEOM_Object thePoint1,
                     in GEOM_Object thePoint2);

    GEOM_Object MakePipe (in GEOM_Object theBase, in GEOM_Object thePath);

    GEOM_Object MakeRevolutionAxisAngle (in GEOM_Object theBase,
                          in GEOM_Object theAxis,
                          in double theAngle);

    GEOM_Object MakeFilling (in GEOM_Object theShape,
                    in long theMinDeg, in long theMaxDeg,
                    in double theTol2D, in double theTol3D,
                    in long theNbIter);

    GEOM_Object MakeThruSections(in ListOfGO theSeqSections,
                     in boolean theModeSolid,
                     in double thePreci,
                                 in boolean theRuled);

    GEOM_Object MakePipeWithDifferentSections (in ListOfGO theSeqBases,
                                in ListOfGO theLocations,
                                in GEOM_Object thePath,
                                in boolean theWithContact ,
                                in boolean theWithCorrection );
    
  };

  interface GEOM_IShapesOperations : GEOM_IOperations
  {
    GEOM_Object MakeEdge (in GEOM_Object thePnt1, in GEOM_Object thePnt2);

    GEOM_Object MakeWire (in ListOfGO theEdgesAndWires);

    GEOM_Object MakeFace (in GEOM_Object theWire, in boolean isPlanarWanted);

    GEOM_Object MakeFaceWires (in ListOfGO theWires, in boolean isPlanarWanted);

    GEOM_Object MakeShell (in ListOfGO theFacesAndShells);

    GEOM_Object MakeSolidShell (in GEOM_Object theShell);

    GEOM_Object MakeSolidShells (in ListOfGO theShells);

    GEOM_Object MakeCompound (in ListOfGO theShapes);

    GEOM_Object MakeGlueFaces (in GEOM_Object theShape, in double theTolerance);

    ListOfGO MakeExplode (in GEOM_Object theShape,
                 in long        theShapeType,
                 in boolean     isSorted);

    ListOfLong SubShapeAllIDs (in GEOM_Object theShape,
                      in long        theShapeType,
                      in boolean     isSorted);

    GEOM_Object GetSubShape (in GEOM_Object theMainShape,
                    in long        theID);

    long GetSubShapeIndex (in GEOM_Object theMainShape, in GEOM_Object theSubShape);

    long GetTopologyIndex (in GEOM_Object theMainShape, in GEOM_Object theSubShape);

    string GetShapeTypeString (in GEOM_Object theShape);

    long NumberOfFaces (in GEOM_Object theShape);

    long NumberOfEdges (in GEOM_Object theShape);

    GEOM_Object ChangeOrientation (in GEOM_Object theShape);

    ListOfLong GetFreeFacesIDs (in GEOM_Object theShape);

    ListOfGO GetSharedShapes (in GEOM_Object theShape1,
                     in GEOM_Object theShape2,
                     in long        theShapeType);

    ListOfGO GetShapesOnPlane (in GEOM_Object theShape,
                      in long        theShapeType,
                      in GEOM_Object theAx1,
                      in shape_state theState);

    ListOfGO GetShapesOnCylinder (in GEOM_Object theShape,
                      in long        theShapeType,
                      in GEOM_Object theAxis,
                      in double      theRadius,
                      in shape_state theState);

    ListOfGO GetShapesOnSphere (in GEOM_Object theShape,
                    in long        theShapeType,
                    in GEOM_Object theCenter,
                    in double      theRadius,
                    in shape_state theState);

    ListOfGO GetShapesOnQuadrangle (in GEOM_Object theShape,
                                    in long        theShapeType,
                                    in GEOM_Object theTopLeftPoint,
                                    in GEOM_Object theTopRigthPoint,
                                    in GEOM_Object theBottomLeftPoint,
                                    in GEOM_Object theBottomRigthPoint,
                                    in shape_state theState);

    ListOfLong GetShapesOnPlaneIDs (in GEOM_Object theShape,
                        in long        theShapeType,
                        in GEOM_Object theAx1,
                        in shape_state theState);

    ListOfLong GetShapesOnCylinderIDs (in GEOM_Object theShape,
                           in long        theShapeType,
                           in GEOM_Object theAxis,
                           in double      theRadius,
                           in shape_state theState);

    ListOfLong GetShapesOnSphereIDs (in GEOM_Object theShape,
                         in long        theShapeType,
                         in GEOM_Object theCenter,
                         in double      theRadius,
                         in shape_state theState);

    ListOfLong GetShapesOnQuadrangleIDs (in GEOM_Object theShape,
                                         in long        theShapeType,
                                         in GEOM_Object theTopLeftPoint,
                                         in GEOM_Object theTopRigthPoint,
                                         in GEOM_Object theBottomLeftPoint,
                                         in GEOM_Object theBottomRigthPoint,
                                         in shape_state theState);

    GEOM_Object GetInPlace (in GEOM_Object theShapeWhere,
                   in GEOM_Object theShapeWhat);
  };

  interface GEOM_IBlocksOperations : GEOM_IOperations
  {
    GEOM_Object MakeQuad (in GEOM_Object theEdge1,
                 in GEOM_Object theEdge2,
                 in GEOM_Object theEdge3,
                 in GEOM_Object theEdge4);

    GEOM_Object MakeQuad2Edges (in GEOM_Object theEdge1,
                    in GEOM_Object theEdge2);

    GEOM_Object MakeQuad4Vertices (in GEOM_Object thePnt1,
                       in GEOM_Object thePnt2,
                       in GEOM_Object thePnt3,
                       in GEOM_Object thePnt4);

    GEOM_Object MakeHexa (in GEOM_Object theFace1,
                 in GEOM_Object theFace2,
                 in GEOM_Object theFace3,
                 in GEOM_Object theFace4,
                 in GEOM_Object theFace5,
                 in GEOM_Object theFace6);

    GEOM_Object MakeHexa2Faces (in GEOM_Object theFace1,
                    in GEOM_Object theFace2);

    GEOM_Object GetPoint (in GEOM_Object theShape,
                 in double      theX,
                 in double      theY,
                 in double      theZ,
                 in double      theEpsilon);

    GEOM_Object GetEdge (in GEOM_Object theShape,
                in GEOM_Object thePoint1,
                in GEOM_Object thePoint2);

    GEOM_Object GetEdgeNearPoint (in GEOM_Object theShape,
                      in GEOM_Object thePoint);

    GEOM_Object GetFaceByPoints (in GEOM_Object theShape,
                     in GEOM_Object thePoint1,
                     in GEOM_Object thePoint2,
                     in GEOM_Object thePoint3,
                     in GEOM_Object thePoint4);

    GEOM_Object GetFaceByEdges (in GEOM_Object theShape,
                    in GEOM_Object theEdge1,
                    in GEOM_Object theEdge2);

    GEOM_Object GetOppositeFace (in GEOM_Object theBlock,
                     in GEOM_Object theFace);

    GEOM_Object GetFaceNearPoint (in GEOM_Object theShape,
                      in GEOM_Object thePoint);

    GEOM_Object GetFaceByNormale (in GEOM_Object theBlock,
                      in GEOM_Object theVector);

    boolean IsCompoundOfBlocks (in GEOM_Object theCompound,
                    in long        theMinNbFaces,
                    in long        theMaxNbFaces,
                    out long       theNbBlocks);

    enum BCErrorType
    {
      /* Each element of the compound should be a Block */
      NOT_BLOCK,

      /* An element is a potential block, but has degenerated and/or seam edge(s). */
      EXTRA_EDGE,

      /* A connection between two Blocks should be an entire face or an entire edge */
      INVALID_CONNECTION,

      /* The compound should be connexe */
      NOT_CONNECTED,

      /* The glue between two quadrangle faces should be applied */
      NOT_GLUED
    };

    struct BCError
    {
      BCErrorType error;
      ListOfLong  incriminated;
    };

    typedef sequence<BCError> BCErrors;

    boolean CheckCompoundOfBlocks (in GEOM_Object theCompound,
                       out BCErrors   theErrors);

    string PrintBCErrors (in GEOM_Object theCompound,
                 in BCErrors    theErrors);

    GEOM_Object RemoveExtraEdges (in GEOM_Object theShape);

    GEOM_Object CheckAndImprove (in GEOM_Object theCompound);

    ListOfGO ExplodeCompoundOfBlocks (in GEOM_Object theCompound,
                          in long        theMinNbFaces,
                          in long        theMaxNbFaces);

    GEOM_Object GetBlockNearPoint (in GEOM_Object theCompound,
                       in GEOM_Object thePoint);

    GEOM_Object GetBlockByParts (in GEOM_Object theCompound,
                     in ListOfGO    theParts);

    ListOfGO GetBlocksByParts (in GEOM_Object theCompound,
                      in ListOfGO    theParts);

    GEOM_Object MakeMultiTransformation1D (in GEOM_Object theBlock,
                            in long        theDirFace1,
                            in long        theDirFace2,
                            in long        theNbTimes);

    GEOM_Object MakeMultiTransformation2D (in GEOM_Object theBlock,
                            in long        theDirFace1U,
                            in long        theDirFace2U,
                            in long        theNbTimesU,
                            in long        theDirFace1V,
                            in long        theDirFace2V,
                            in long        theNbTimesV);

    ListOfGO Propagate (in GEOM_Object theShape);
  };

  interface GEOM_IBooleanOperations : GEOM_IOperations
  {
    GEOM_Object MakeBoolean (in GEOM_Object theShape1,
                    in GEOM_Object theShape2,
                    in long theOperation);

    GEOM_Object MakePartition (in ListOfGO   theShapes,
                      in ListOfGO   theTools,
                      in ListOfGO   theKeepInside,
                      in ListOfGO   theRemoveInside,
                      in short      theLimit,
                      in boolean    theRemoveWebs,
                      in ListOfLong theMaterials);

    GEOM_Object MakeHalfPartition (in GEOM_Object theShape,
                       in GEOM_Object thePlane);
  };

  interface GEOM_ICurvesOperations : GEOM_IOperations
  {
    GEOM_Object MakeCirclePntVecR (in GEOM_Object thePnt,
                       in GEOM_Object theVec,
                       in double theR);
    GEOM_Object MakeCircleThreePnt (in GEOM_Object thePnt1,
                        in GEOM_Object thePnt2,
                        in GEOM_Object thePnt3);

    GEOM_Object MakeEllipse (in GEOM_Object thePnt,
                    in GEOM_Object theVec,
                    in double theRMajor,
                    in double theRMinor);

    GEOM_Object MakeArc (in GEOM_Object thePnt1,
                in GEOM_Object thePnt2,
                in GEOM_Object thePnt3);

    GEOM_Object MakePolyline (in ListOfGO thePoints);

    GEOM_Object MakeSplineBezier (in ListOfGO thePoints);

    GEOM_Object MakeSplineInterpolation (in ListOfGO thePoints);

    GEOM_Object MakeSketcher (in string theCommand, in ListOfDouble theWorkingPlane);

    GEOM_Object MakeSketcherOnPlane (in string theCommand, in GEOM_Object theWorkingPlane);
  };

  interface GEOM_ILocalOperations : GEOM_IOperations
  {
    GEOM_Object MakeFilletAll (in GEOM_Object theShape,
                      in double      theR);

    GEOM_Object MakeFilletEdges (in GEOM_Object theShape,
                     in double      theR,
                     in ListOfLong  theEdges);

    GEOM_Object MakeFilletFaces (in GEOM_Object theShape,
                     in double      theR,
                     in ListOfLong  theFaces);

    GEOM_Object MakeChamferAll (in GEOM_Object theShape,
                    in double      theD);

    GEOM_Object MakeChamferEdge (in GEOM_Object theShape,
                     in double theD1, in double theD2,
                     in long theFace1, in long theFace2);

    GEOM_Object MakeChamferFaces (in GEOM_Object theShape,
                      in double theD1, in double theD2,
                      in ListOfLong theFaces);

    GEOM_Object MakeArchimede (in GEOM_Object theShape,
                      in double theWeight,
                      in double theWaterDensity,
                      in double theMeshDeflection);

    long GetSubShapeIndex (in GEOM_Object theShape, in GEOM_Object theSubShape);
  };

  interface GEOM_IHealingOperations : GEOM_IOperations
  {
    GEOM_Object ProcessShape (in GEOM_Object theShapes,
                     in string_array theOperators,
                     in string_array theParameters,
                     in string_array theValues);

    void GetShapeProcessParameters (out string_array theOperators,
                        out string_array theParameters,
                        out string_array theValues);
    void GetOperatorParameters (in string theOperator,
                    out string_array theParameters,
                    out string_array theValues);

    GEOM_Object SuppressFaces (in GEOM_Object theObject, in short_array theFaces);

    GEOM_Object CloseContour (in GEOM_Object theObject, in short_array theWires,
                     in boolean isCommonVertex);

    GEOM_Object RemoveIntWires (in GEOM_Object theObject, in short_array theWires);

    GEOM_Object FillHoles (in GEOM_Object theObject, in short_array theWires);

    GEOM_Object Sew (in GEOM_Object theObject, in double theTolerance);

    GEOM_Object DivideEdge (in GEOM_Object theObject, in short theEdgeIndex,
                   in double theValue, in boolean isByParameter);

    boolean GetFreeBoundary (in GEOM_Object theObject,
                    out ListOfGO theClosedWires,
                    out ListOfGO theOpenWires);

    GEOM_Object ChangeOrientation (in GEOM_Object theObject);
    GEOM_Object ChangeOrientationCopy (in GEOM_Object theObject);

  };

  interface GEOM_IInsertOperations : GEOM_IOperations
  {
    GEOM_Object MakeCopy (in GEOM_Object theOriginal);

    void Export (in GEOM_Object theObject, in string theFileName, in string theFormatName);

    GEOM_Object Import (in string theFileName, in string theFormatName);

    void ImportTranslators (out string_array theFormats,
                   out string_array thePatterns);

    void ExportTranslators (out string_array theFormats,
                   out string_array thePatterns);
  };

  interface GEOM_IMeasureOperations : GEOM_IOperations
  {
    void GetBasicProperties (in GEOM_Object theShape,
                    out double theLength,
                    out double theSurfArea,
                    out double theVolume);

    GEOM_Object GetCentreOfMass (in GEOM_Object theShape);

    void GetInertia (in GEOM_Object theShape,
               out double I11, out double I12, out double I13,
               out double I21, out double I22, out double I23,
               out double I31, out double I32, out double I33,
               out double Ix , out double Iy , out double Iz);

    void GetBoundingBox (in GEOM_Object theShape,
                out double Xmin, out double Xmax,
                out double Ymin, out double Ymax,
                out double Zmin, out double Zmax);

    void GetTolerance (in GEOM_Object theShape,
                 out double FaceMin, out double FaceMax,
                 out double EdgeMin, out double EdgeMax,
                 out double VertMin, out double VertMax);

    boolean CheckShape (in GEOM_Object theShape,
               out string     theDescription);

    boolean CheckShapeWithGeometry (in GEOM_Object theShape,
                        out string     theDescription);

    string WhatIs (in GEOM_Object theShape);

    double GetMinDistance (in GEOM_Object theShape1, in GEOM_Object theShape2,
                  out double X1, out double Y1, out double Z1,
                  out double X2, out double Y2, out double Z2);


    void PointCoordinates (in GEOM_Object theShape, out double X, out double Y, out double Z);
  };


  interface GEOM_IGroupOperations : GEOM_IOperations
  {
    GEOM_Object CreateGroup (in GEOM_Object theMainShape, in long theShapeType);

    void AddObject (in GEOM_Object theGroup, in long theSubShapeId);

    void RemoveObject (in GEOM_Object theGroup, in long theSubShapeId);

    void UnionList (in GEOM_Object theGroup, in ListOfGO theSubShapes);

    void DifferenceList (in GEOM_Object theGroup, in ListOfGO theSubShapes);

    void UnionIDs (in GEOM_Object theGroup, in ListOfLong theSubShapes);

    void DifferenceIDs (in GEOM_Object theGroup, in ListOfLong theSubShapes);

    long GetType (in GEOM_Object theGroup);

    GEOM_Object GetMainShape (in GEOM_Object theGroup);

    ListOfLong GetObjects (in GEOM_Object theGroup);
  };


  interface GEOM_Gen : Engines::Component,SALOMEDS::Driver
  {
    void Undo (in long theStudyID);

    void Redo (in long theStudyID);

    SALOMEDS::SObject AddInStudy (in SALOMEDS::Study theStudy,
                      in GEOM_Object theObject,
                      in string theName,
                      in GEOM_Object theFather);

    GEOM_IBasicOperations     GetIBasicOperations    (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_ITransformOperations GetITransformOperations(in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_I3DPrimOperations    GetI3DPrimOperations   (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IShapesOperations    GetIShapesOperations   (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IBooleanOperations   GetIBooleanOperations  (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_ICurvesOperations    GetICurvesOperations   (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_ILocalOperations     GetILocalOperations    (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IHealingOperations   GetIHealingOperations  (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IInsertOperations    GetIInsertOperations   (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IMeasureOperations   GetIMeasureOperations  (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IBlocksOperations    GetIBlocksOperations   (in long theStudyID) raises (SALOME::SALOME_Exception);
    GEOM_IGroupOperations     GetIGroupOperations    (in long theStudyID) raises (SALOME::SALOME_Exception);

    void RemoveObject (in GEOM_Object theObject);

    GEOM_Object GetObject (in long theStudyID, in string theEntry);

    GEOM_Object AddSubShape (in GEOM_Object theMainShape, in ListOfLong theIndices);

    GEOM_Object GetIORFromString (in string theIOR);

    string GetStringFromIOR (in GEOM_Object theObject);

    string GetDumpName (in string theStudyEntry);

    string_array GetAllDumpNames();
  };
};

#endif

Generated on Wed Jul 26 11:28:15 2006 for SALOME - GEOM - v.3.2.1 by  1.4.6